ESP + Reorganizacja

ESP32/06-DimmableLED/06-DimmableLED.ino

@@ -0,0 +1,88 @@
+/*********************************************************************************
+ *  MIT License
+ *  
+ *  Copyright (c) 2020-2024 Gregg E. Berman
+ *  
+ *  https://github.com/HomeSpan/HomeSpan
+ *  
+ *  Permission is hereby granted, free of charge, to any person obtaining a copy
+ *  of this software and associated documentation files (the "Software"), to deal
+ *  in the Software without restriction, including without limitation the rights
+ *  to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
+ *  copies of the Software, and to permit persons to whom the Software is
+ *  furnished to do so, subject to the following conditions:
+ *  
+ *  The above copyright notice and this permission notice shall be included in all
+ *  copies or substantial portions of the Software.
+ *  
+ *  THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
+ *  IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
+ *  FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
+ *  AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
+ *  LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
+ *  OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
+ *  SOFTWARE.
+ *  
+ ********************************************************************************/
+ 
+////////////////////////////////////////////////////////////
+//                                                        //
+//    HomeSpan: A HomeKit implementation for the ESP32    //
+//    ------------------------------------------------    //
+//                                                        //
+// Example 6: One working on/off LED and one working     //
+//            dimmable LED, both based on the LightBulb   //
+//            Service                                     //
+//                                                        //
+////////////////////////////////////////////////////////////
+
+
+#include "HomeSpan.h" 
+#include "DEV_LED.h"          
+
+void setup() {
+
+  // Example 6 changes Example 5 so that LED #2 is now dimmable, instead of just on/off.  This requires us to create a new
+  // derived Service we will name "DEV_DimmableLED"  Instead of creating a new file to store this definition, we will simply
+  // tack it on to the end of the DEV_LED.h file that includes the code we created in Example 5 to control an on/off LED.
+  // Grouping similar-style Services in one ".h" file makes it easier to organize your custom devices.
+
+  // As usual, all previous comments have been deleted and only new changes from the previous example are shown.
+
+  // NOTE: The Arduino/ESP32 code base does not include the function analogWrite() which is typically used to create a PWM
+  // output to drive the brightness of an LED.  Instead, the ESP32 code base itself includes a set of functions to create PWM output
+  // and the ESP32 chip has built-in PWM functionality specifically for this purpose.
+  
+  // HomeSpan wraps all of this PWM functionality into a single integrated class called LedPin, making it very easy to define
+  // dimmable LED pins and set the PWM level (i.e. duty cycle) from 0-100%.  Use of this LedPin class is shown in DEV_DimmableLED.
+  
+  Serial.begin(115200);
+
+  homeSpan.setPairingCode("11122333");
+  homeSpan.setQRID("111-22-333");
+
+  homeSpan.begin(Category::Lighting,"HomeSpan LED");
+  
+  new SpanAccessory(); 
+  
+    new Service::AccessoryInformation(); 
+      new Characteristic::Identify();                
+
+    new DEV_LED(16);                // create an on/off LED attached to pin 16 (same as in Example 5)
+
+  new SpanAccessory(); 
+  
+    new Service::AccessoryInformation();    
+      new Characteristic::Identify();                       
+  
+    new DEV_DimmableLED(2);        // NEW! create a dimmable (PWM-driven) LED attached to pin 17.  See new code at end of DEV_LED.h
+
+} // end of setup()
+
+//////////////////////////////////////
+
+void loop(){
+  
+  homeSpan.poll();
+  
+} // end of loop()

ESP32/06-DimmableLED/DEV_LED.h

@@ -0,0 +1,67 @@
+
+////////////////////////////////////
+//   DEVICE-SPECIFIC LED SERVICES //
+////////////////////////////////////
+
+struct DEV_LED : Service::LightBulb {               // ON/OFF LED
+
+  int ledPin;                                       // pin number defined for this LED
+  SpanCharacteristic *power;                        // reference to the On Characteristic
+  
+  DEV_LED(int ledPin) : Service::LightBulb(){       // constructor() method
+
+    power=new Characteristic::On();                 
+    this->ledPin=ledPin;                            
+    pinMode(ledPin,OUTPUT);                         
+    
+  } // end constructor
+
+  boolean update(){                              // update() method
+
+    digitalWrite(ledPin,power->getNewVal());      
+   
+    return(true);                               // return true
+  
+  } // update
+};
+      
+//////////////////////////////////
+
+// Here's the new code defining DEV_DimmableLED - changes from above are noted in the comments
+
+struct DEV_DimmableLED : Service::LightBulb {       // Dimmable LED
+
+  LedPin *ledPin;                                   // NEW! Create reference to LED Pin instantiated below
+  SpanCharacteristic *power;                        // reference to the On Characteristic
+  SpanCharacteristic *level;                        // NEW! Create a reference to the Brightness Characteristic instantiated below
+  
+  DEV_DimmableLED(int pin) : Service::LightBulb(){       // constructor() method
+
+    power=new Characteristic::On();     
+                
+    level=new Characteristic::Brightness(50);       // NEW! Instantiate the Brightness Characteristic with an initial value of 50% (same as we did in Example 4)
+    level->setRange(5,100,1);                       // NEW! This sets the range of the Brightness to be from a min of 5%, to a max of 100%, in steps of 1% (different from Example 4 values)
+
+    this->ledPin=new LedPin(pin);                   // NEW! Configures a PWM LED for output to the specified pin.  Note pinMode() does NOT need to be called in advance
+    
+  } // end constructor
+
+  boolean update(){                              // update() method
+
+    // Here we set the brightness of the LED by calling ledPin->set(brightness), where brightness=0-100.
+    // Note HomeKit sets the on/off status of a LightBulb separately from its brightness, which means HomeKit
+    // can request a LightBulb be turned off, but still retains the brightness level so that it does not need
+    // to be resent once the LightBulb is turned back on.
+    
+    // Multiplying the newValue of the On Characteristic ("power", which is a boolean) with the newValue of the
+    // Brightness Characteristic ("level", which is an integer) is a short-hand way of creating the logic to
+    // set the LED level to zero when the LightBulb is off, or to the current brightness level when it is on.
+    
+    ledPin->set(power->getNewVal()*level->getNewVal());    
+   
+    return(true);                               // return true
+  
+  } // update
+};
+      
+//////////////////////////////////